home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 14 / CU Amiga Magazine's Super CD-ROM 14 (1997)(EMAP Images)(GB)(Track 1 of 3)[!][issue 1997-09].iso / CUCD / Programming / Mesa-2.2 / widgets-mesa / configure.in < prev    next >
Encoding:
Text File  |  1997-02-15  |  4.7 KB  |  145 lines
  1. # configure.in --- Mesa GL Widget for X11 Toolkit Programming
  2. # Copyright (C) 1995 by
  3. #   Jeroen van der Zijp <jvz@cyberia.cfdrc.com>
  4. #   Thorsten Ohl <Thorsten.Ohl@Physik.TH-Darmstadt.de>
  5. #
  6. # This library is free software; you can redistribute it and/or
  7. # modify it under the terms of the GNU Library General Public
  8. # License as published by the Free Software Foundation; either
  9. # version 2 of the License, or (at your option) any later version.
  10. #
  11. # This library is distributed in the hope that it will be useful,
  12. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14. # GNU Library General Public License for more details.
  15. #
  16. # You should have received a copy of the GNU Library General Public
  17. # License along with this library; if not, write to the Free Software
  18. # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  19. #
  20. # $Id: configure.in,v 1.16 1996/09/27 10:21:52 ohl Exp $
  21. #
  22. ########################################################################
  23. AC_INIT([src/GLwDrawingArea.c])dnl
  24. AC_CANONICAL_HOST
  25. AC_PROG_INSTALL
  26. AC_PROG_LN_S
  27. AC_CHECK_PROG([POD2MAN], [pod2man], [pod2man])dnl
  28. AC_CHECK_PROG([POD2HTML], [pod2html], [pod2html])dnl
  29. AC_PROG_RANLIB
  30. ARFLAGS="ruv"
  31. AC_SUBST([ARFLAGS])dnl
  32. AC_SUBST([SYS_CFLAGS])dnl
  33. AC_SUBST([SYS_LDFLAGS])dnl
  34. AC_PROG_CC
  35. test "$CC" = "gcc" && SYS_CFLAGS="$SYS_CFLAGS -pipe -Wall"
  36. AC_PROG_CPP
  37. # Query Brian Paul's database for compiling Mesa:
  38. case "$host" in
  39.   *-hp-hpux*)
  40.     SYS_CFLAGS="$SYS_CFLAGS -D_HPUX_SOURCE"
  41.     test "$CC" = "cc" || SYS_CFLAGS="$SYS_CFLAGS +O2 +Oall +Onolimit -Aa"
  42.     ;;
  43.   mips-sgi-irix4*)
  44.     test "$CC" = "cc" || SYS_CFLAGS="$SYS_CFLAGS -float"
  45.     ARFLAGS="rcv"
  46.     ;;
  47.   mips-sgi-irix5*)
  48.     # On IRIX 5.3 -sopt causes a problem in drawpixels.c so we don't use it
  49.     test "$CC" = "cc" || \
  50.       SYS_CFLAGS="$SYS_CFLAGS -ansi -float"
  51.     ARFLAGS="rcv"
  52.     ;;
  53.   mips-sgi-irix6*)
  54.     #   1068 - integer conversion resulted in a change of sign
  55.     #   1069 - integer conversion resulted in truncation
  56.     #   1174 - variable was declared but never referenced
  57.     #   1185 - enumerated type mixed with another type
  58.     #   1209 - controlling expression is constant
  59.     #   1474 - declaring a void parameter list with a typedef is nonstandard
  60.     #   1552 - variable was set but never used
  61.     test "$CC" = "cc" || \
  62.       SYS_CFLAGS="$SYS_CFLAGS"
  63.     ARFLAGS="rcv"
  64.     ;;
  65.   *-linux*)
  66.     SYS_CFLAGS="$SYS_CFLAGS -DSHM"
  67.     SYS_LDFLAGS="$SYS_LDFLAGS"
  68.     ;;
  69.   *-netbsd*)
  70.     ARFLAGS="rcv"
  71.     ;;
  72.   alpha-dec-osf*)
  73.     test "$CC" = "gcc" || SYS_CFLAGS="$SYS_CFLAGS -std1 -DSHM"
  74.     ;;
  75.   sparc-sun-solaris2*)
  76.     test "$CC" = "gcc" || SYS_CFLAGS="$SYS_CFLAGS -Xa"
  77.     ;;
  78.   *-ultrix*)
  79.     test "$CC" = "gcc" || SYS_CFLAGS="$SYS_CFLAGS -Dconst=/**/"
  80.     ARFLAGS="rusv"
  81.     ;;
  82. esac
  83. AC_PATH_XTRA
  84. # It has been reported that some vendors don't ship libXmu.
  85. # Allow to compile a stripped down widget set w/o the colormap functions.
  86. if test -n "$x_libraries"; then
  87.   ac_save_LDFLAGS="$LDFLAGS"
  88.   LDFLAGS="$LDFLAGS -L$x_libraries"
  89.   AC_CHECK_LIB(Xmu, XmuRegisterExternalAgent,
  90.                [XMU_LIB="-lXmu"; AC_DEFINE([HAVE_XMU])], , $X_EXTRA_LIBS)
  91.   LDFLAGS="$ac_save_LDFLAGS"
  92. fi
  93. AC_SUBST([HAVE_XMU])
  94. AC_SUBST([XMU_LIB])
  95. # Some vendors don't ship libXaw.
  96. if test -n "$x_libraries"; then
  97.   ac_save_LDFLAGS="$LDFLAGS"
  98.   LDFLAGS="$LDFLAGS -L$x_libraries"
  99.   AC_CHECK_LIB(Xaw, XawInitializeWidgetSet,
  100.                [XAW_LIB="-lXaw"
  101.                 AC_DEFINE([HAVE_XAW])
  102.                 XAW_DEMOS="cube mcube ed tea"],
  103.                [XAW_DEMOS=],
  104.                [$XMU_LIB -lXt -lX11 $X_EXTRA_LIBS])
  105.   LDFLAGS="$ac_save_LDFLAGS"
  106. fi
  107. AC_SUBST([HAVE_XAW])
  108. AC_SUBST([XAW_LIB])
  109. AC_SUBST([XAW_DEMOS])
  110. AC_HEADER_STDC
  111. AC_C_CONST
  112. AC_C_INLINE
  113. AC_CHECK_FUNCS(strchr memcpy memmove)dnl
  114. AC_ARG_ENABLE(debug,
  115.   [  --enable-debug          also compile debugging code],
  116.   [case x$withval in
  117.     xno) ;;
  118.     x*)  AC_DEFINE([DEBUG]);;
  119.    esac])dnl
  120. AC_ARG_WITH(motif,
  121.   [  --with-motif            also compile the Motif widgets (untested)],
  122.   [case x$withval in
  123.     xno) MOTIF_OBJS=; MOTIF_DEMOS=;;
  124.     x*)  AC_CHECK_HEADER([Xm/Xm.h],
  125.            [MOTIF_OBJS="GLwMDrawingArea.o GLwCreateMDrawingArea.o dnl
  126.                         MesaMDrawingArea.o GLwMMakeCurrent.o dnl
  127.                         MesaMWorkstation.o";
  128.             MOTIF_DEMOS=""]);;
  129.    esac],
  130.   [MOTIF_OBJS=; MOTIF_DEMOS=])dnl
  131. AC_SUBST([MOTIF_OBJS])dnl
  132. AC_SUBST([MOTIF_DEMOS])dnl
  133. AC_ARG_WITH(mesadir,
  134.   [  --with-mesadir=PATH     use the Mesa tree rooted in PATH (default: ..)],
  135.   [case x$withval in
  136.     xno) mesa_srcdir="`pwd`";;
  137.     x)   mesa_srcdir="`cd .. && pwd`";;
  138.     x*)  mesa_srcdir="`cd $withval && pwd`";;
  139.    esac],
  140.   [mesa_srcdir="`cd .. && pwd`"])dnl
  141. AC_SUBST([mesa_srcdir])dnl
  142. AC_OUTPUT([Makefile src/Makefile include/GL/Makefile
  143.            demos/Makefile man/Makefile])dnl
  144.  
  145.